; 其他脚本可以向此脚本发送消息：指定时间和内容，此脚本将会在指定时间后提示
; 适合在专注工作时，起提醒效果

; 它需要配合其他脚本，我使用的是仓库 ahk-meow-tool

#Include g:\AHK\git-ahk-lib\Theme.ahk
#Include g:\AHK\git-ahk-lib\Tip.ahk
#Include g:\AHK\git-ahk-lib\util\Animation.ahk
#Include g:\AHK\git-ahk-lib\util\message\Receiver.ahk
#Include G:\AHK\git-ahk-lib\util\log\log.ahk

logger_toast := Log('.\toast_log.txt')

Receiver.OnCopyDataCB := CB

CB(data) {
  period := data.substring(1, i := InStr(data, '@'))
  detail := data.substring(i + 1)
  logger_toast.Info('[start] ' data), Tip.ShowTip('收到任务')
  SetTimer(Toast.Bind(detail, FormatTime(, 'HH:mm:ss'), period), period * 1e3 * -1)
}

Toast(str, date, period) {
  g := Gui('+AlwaysOnTop +ToolWindow -Caption +Border')
  g.SetFont('s14', 'consolas')
  g.AddText('Section', str).GetPos(, , &w)
  g.AddText('xs y34 Backgroundffd500 h1 w' w)
  g.SetFont('s13')
  g.AddText('xs y35', FormatTime(, date ' - HH:mm:ss -- ' period))
  g.OnEvent('ContextMenu', (*) => g.Destroy())
  Theme.Dark(g)
  g.Show('Hide'), g.GetPos(, , &w, &h)
  p := g.AddText('x0 y' h - 4 ' Backgroundff2323 h3 w' w)
  g.Move(A_ScreenWidth - w, A_ScreenHeight - h), g.Show('NA')
  t := 200, a := 15000
  loop t {
    p.Move(, , w - (w / t) * A_Index)
    Sleep a / t
  }
  Animation.FadeOut(g, , 50)
  logger_toast.Info('[done] ' str) ; 记录
}