buildscript {
    repositories {
        maven { url 'https://maven.aliyun.com/repository/public/' }
        maven { url 'https://maven.aliyun.com/repository/spring/' }
        maven { url 'https://maven.aliyun.com/nexus/content/repositories/jcenter/'}
    }
}
plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
    id 'org.springframework.boot' version '3.2.3'
    id 'io.spring.dependency-management' version '1.1.4'
}
java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
        vendor = JvmVendorSpec.ORACLE
    }
}

static def setupBootJarProject(task, project) {
    task.enabled = true
    if (project.hasProperty('bootJarArchiveId')) {
        task.archiveFileName = "${project.bootJarArchiveId}.${task.archiveExtension.get()}"
    }
}

allprojects {
    group = 'com.chatplus.application'
    version = '1.0.0-SNAPSHOT'

    ext {
        jacksonVersion = '2.16.1'
        schelockVersion = '4.12.0'
        jsonpathVersion = '2.4.0'
        mysqlVersion = '8.0.33'
        mybatisPlusVersion = '3.5.5'
        redissonVersion = '3.27.1'
        commonsCollectionsVersion = '4.4'
        guavaVersion = '33.0.0-jre'
        jacksonMapperAslVersion = '1.9.13'
        powerMockVersion = '2.0.5'
        hutoolVersion = '5.8.26'
        aliyunSdkAfs = '1.0.1'
        aliyunSdk = '4.1.0'
        jjwtVersion = '0.11.2'
        poiVersion = '5.1.0'
        elasticsearchVersion = '7.16.3'
        wechatSdk = '4.6.0'
        alipayEasySdk = '2.2.3'
        xxlJobVersion = '2.4.0'
        pinYin4JVersion = '2.5.1'
        logstashLogback = '7.2'
        autopoiVersion = '1.4.3'
        jiebaVersion = '1.0.2'
        saTokenVersion = '1.37.0'
        sms4jVersion = '2.2.0'
        dynamicDatasourceVersion = '4.3.0'
        springCloudStarterBootstrapVersion = '4.1.0'
        lombokVersion = '1.18.30'
    }

    configurations.configureEach {
        exclude module: 'spring-boot-starter-tomcat'
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
    }

    repositories {
        maven { url 'https://maven.aliyun.com/repository/public/'  }
        maven { url 'https://maven.aliyun.com/repository/spring/' }
        maven { url 'https://maven.aliyun.com/nexus/content/repositories/jcenter/' }
    }
    tasks.register('showVersion') {
        doLast {
            println 'Version: ' + project.version
        }
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'

    dependencies {
        implementation "com.fasterxml.jackson.module:jackson-module-kotlin"
        implementation "jakarta.json:jakarta.json-api:2.1.3"
        implementation 'org.codehaus.janino:janino:3.1.11'
        // 升级springboot 3后要注意改这个版本
        implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.4.0'
        annotationProcessor "org.springframework.boot:spring-boot-configuration-processor"

        testImplementation "org.springframework.boot:spring-boot-starter-test"
        testImplementation "org.powermock:powermock-module-junit4:$powerMockVersion"
        testImplementation "org.powermock:powermock-api-mockito2:$powerMockVersion"
        // 集成 lombok
        /**
         * compileOnly：只编译时有效，不参与打包。代替旧版本的provided
         * runtimeOnly：打包有效，编译无效
         * annotationProcessor：管理注解处理器，并将其添加到处理器类路径中
         */
        compileOnly "org.projectlombok:lombok:$lombokVersion"
        annotationProcessor "org.projectlombok:lombok:$lombokVersion"
        testCompileOnly "org.projectlombok:lombok:$lombokVersion"
        testAnnotationProcessor "org.projectlombok:lombok:$lombokVersion"
    }

    bootJar {
        duplicatesStrategy = DuplicatesStrategy.WARN
        enabled = false
    }

    compileJava.dependsOn(processResources)

    tasks.withType(JavaCompile).configureEach {
        sourceCompatibility = 21
        targetCompatibility = 21

        options.encoding = "UTF-8"
    }

    jar {
        enabled = true

        manifest {
            attributes 'Implementation-Version': project.version
        }
    }

    javadoc {
        options.encoding = 'UTF-8'
        failOnError = false
    }

    tasks.register('sourceJar', Jar) {
        archiveClassifier.set('sources')
        from sourceSets.main.allSource
    }
    tasks.register('docJar', Jar) {
        dependsOn 'javadoc'
        archiveClassifier.set('javadoc')
        from javadoc.destinationDir
    }

    test {
        minHeapSize = "1024m"
        maxHeapSize = "2048m"
    }
}

copy {
    from "git-hooks"
    into ".git/hooks"
}