plugins {
  id "net.saliman.properties" version "1.5.2"
  id "io.spring.dependency-management" version "1.0.11.RELEASE"
  id "com.github.hierynomus.license" version "0.16.1"
  id "org.flywaydb.flyway" version "8.2.0"
  id "org.hidetake.ssh" version "2.10.1"
  id "com.github.johnrengelman.shadow" version "7.1.2"
  id "com.bmuschko.docker-remote-api" version "7.2.0"
  id "org.sonarqube" version "3.3"
  id "com.google.protobuf" version "0.8.18"
}

allprojects {

  apply plugin: "java"
  apply plugin: "java-library"
  apply plugin: "jacoco"
  apply plugin: "checkstyle"
  apply plugin: "net.saliman.properties"
  apply plugin: "io.spring.dependency-management"
  apply plugin: "com.github.johnrengelman.shadow"
  apply plugin: "com.github.hierynomus.license"

  apply from: "${rootDir}/gradle/dm.gradle"

  version = "1.0.0-SNAPSHOT"
  sourceCompatibility = "11"
  targetCompatibility = "11"

  ext {
    protobufVersion = "3.19.3"
    grpcVersion = "1.43.2"
    reactorGrpcVersion = "1.2.3"
  }

  [compileJava, compileTestJava, javadoc]*.options*.encoding = "UTF-8"

  test {
    useJUnitPlatform()
    testLogging {
      exceptionFormat "full"
      events "passed", "skipped", "failed"
    }
    workingDir rootProject.rootDir
    ignoreFailures = true
  }

  jacoco {
    toolVersion = "0.8.3"
  }

  jacocoTestReport {
    reports {
      xml.enabled = true
      html.enabled = true
    }
  }

  license {
    ignoreFailures = true
    header = rootProject.file("LICENSE")
    headerURI = com.hierynomus.gradle.license.LicenseBasePlugin.classLoader.getResource("headers/Apache-2.0").toURI()
    skipExistingHeaders = true
    mapping {
      java = "SLASHSTAR_STYLE"
      conf = "SCRIPT_STYLE"
      proto = "DOUBLESLASH_STYLE"
    }
    ext {
      year = "2019-${Calendar.instance.get(Calendar.YEAR)}"
      author = "the original author or authors"
    }
  }

  checkstyle {
    toolVersion = "8.33"
    configFile = rootProject.file("config/checkstyle/google_checks.xml")
  }

  tasks.withType(Checkstyle) {
    reports {
      xml.enabled = true
      html.enabled = true
    }
  }

  sonarqube {
    properties {
      property "sonar.projectKey", "houge"
      property "sonar.organization", "kevin70"
      property "sonar.host.url", "https://sonarcloud.io"
    }
  }

  dependencies {
    annotationProcessor("org.projectlombok:lombok")
    annotationProcessor("io.avaje:avaje-inject-generator")
    annotationProcessor("com.dslplatform:dsl-json-java8")

    compileOnly("org.projectlombok:lombok")
    compileOnly("com.google.code.findbugs:jsr305")

    implementation("io.avaje:avaje-inject")
    implementation("org.apache.logging.log4j:log4j-core")
    implementation("org.apache.logging.log4j:log4j-slf4j18-impl")
    implementation("com.dslplatform:dsl-json-java8")

    // Test
    testImplementation("org.junit.platform:junit-platform-launcher")
    testImplementation("org.junit.jupiter:junit-jupiter-engine")
    testImplementation("org.junit.jupiter:junit-jupiter-params")
    testImplementation("io.projectreactor:reactor-test")
    testImplementation("io.projectreactor:reactor-tools")
    testImplementation("org.assertj:assertj-core")

    testImplementation("org.mockito:mockito-core")
    testImplementation("com.github.javafaker:javafaker") {
      exclude module: "snakeyaml"
    }
    testImplementation("org.yaml:snakeyaml")
  }

  repositories {
    mavenLocal()
    def aliyunEnabled = System.getenv("GITHUB_ACTIONS") == null
    if (aliyunEnabled) {
      maven { url = "https://maven.aliyun.com/nexus/content/groups/public/" }
    }
    mavenCentral()
    maven { url = "https://oss.sonatype.org/content/repositories/snapshots" }
  }

  jar {
    manifest {
      attributes(
          "Created-By": "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})",
          "Implementation-Title": project.name,
          "Implementation-Version": project.version,
          "Built-Date": java.time.OffsetDateTime.now().truncatedTo(java.time.temporal.ChronoUnit.SECONDS)
      )
    }
  }
}

task prep {
  requiredProperty "houge.postgresql.host"
  requiredProperty "houge.postgresql.user"
  requiredProperty "houge.postgresql.password"
  recommendedProperty "houge.postgresql.port", null, "未配置PostgreSQL端口默认采用[5432]"
  recommendedProperty "houge.db.name", null, "未配置数据库名称默认采用[houge]"
}

// 准备开发环境
task devEnv {
  dependsOn "prep"

  doLast {
    def f = file("${rootDir}/houge.conf")
    if (f.exists()) {
      f.renameTo(file("${rootDir}/houge.conf.${java.time.Instant.now().epochSecond}"))
    }

    f.text = """### Generated ${java.time.LocalDateTime.now()}
poplar {
  r2dbc {
    url = "r2dbc:mysql://${project.property("houge.postgresql.host")}:${findProperty("houge.postgresql.port") ?: 5432}/${findProperty("houge.db.name") ?: "houge"}"
    user = "${project.property("houge.postgresql.user")}"
    password = "${project.property("houge.postgresql.password")}"
  }
}

ws {
  poplar {
    grpc-target = "127.0.0.1:11012"
    stream-grpc-targets = "127.0.0.1:11012"
  }
}

rest {
  poplar {
    grpc-target = "127.0.0.1:11012"
  }
}
"""
  }
}