group 'com.fount4j'
version '1.0.1'

apply plugin: 'java'
apply plugin: 'jdepend'
apply plugin: 'checkstyle'
apply plugin: 'findbugs'

tasks.withType(FindBugs) {
  reports {
    xml.enabled = false
    html.enabled = true
  }
  reportLevel = 'high'
}

sourceCompatibility = 1.7
targetCompatibility = 1.7

[compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'

repositories {
  maven { url "http://maven.aliyun.com/nexus/content/groups/public" }
  mavenCentral()
  jcenter()
}

dependencies {
  // 对 YAML 配置文件的支持
  compile group: 'org.yaml', name: 'snakeyaml', version: '1.17'
  // 模板引擎
  compile group: 'com.ibeetl', name: 'beetl', version: '2.7.3'
  // h2 数据库
  runtime group: 'com.h2database', name: 'h2', version: '1.4.193'
}

task copyFiles(dependsOn: build) {
  copy {
    from fileTree(dir: 'assets', includes: ['data/*.mv.db', 'template/*', 'generator.yml'])
    into 'build/zip/assets'
  }
  copy {
    from 'assets/start.bat'
    into 'build/zip'
  }
  copy {
    from configurations.runtime
    into 'build/zip/libs'
    exclude { details ->
      details.file.name.startsWith('antlr4-annotations') || details.file.name.startsWith('org.abego.treelayout.core')
    }
  }
  // 分成 copyFiles 和 buildZip 两个 task 是因为：
  // 如果不用 doLast 括起来，就会在 jar 文件生成之前执行 copy 动作
  // 如果合并为一个 task，把 copy 动作放在 doLast 中，又会出现 jar 包 copy 之前就执行压缩动作
  // 所以分为两个 task 前面的 task 在执行完所有 copy 动作后再 copy jar 文件
  doLast {
    copy {
      from 'build/libs'
      into 'build/zip'
      rename { String fileName ->
        fileName.replace("-${version}", '')
      }
    }
  }
}

task buildZip(dependsOn: copyFiles, type: Zip) {
  from 'build/zip'
  into "${project.name}-${version}"
}