plugins {
    id "org.jetbrains.kotlin.jvm" version "1.6.10" apply false
}
ext.semver = '3.2'
ext.buildNum = '3200'
ext.distBinDir = file('ganttproject-builder/dist-bin')
ext.pluginsDir = file("ganttproject-builder/dist-bin/plugins/base")

version = "${semver}.${buildNum}"

// Config for all projects: deps come from Maven repository,
// compile using Java 11, libs normally sit in lib
allprojects {
    configurations {
        direct
        providedCompile
    }
    repositories {
        mavenCentral()
        google()
        jcenter()
    }
    apply plugin: 'java'
    ext {
        libDir = 'lib'
        mvnDir = 'lib/mvn'
        kotlin_version = "1.6.10"
        javaExportOptions = [
            '--add-exports', 'javafx.controls/com.sun.javafx.scene.control.behavior=ALL-UNNAMED',
            '--add-exports', 'javafx.base/com.sun.javafx=ALL-UNNAMED',
            '--add-exports', 'javafx.controls/com.sun.javafx.scene.control=ALL-UNNAMED',
            '--add-exports', 'javafx.controls/com.sun.javafx.scene.control.skin=ALL-UNNAMED',
            '--add-exports', 'javafx.controls/com.sun.javafx.scene.control.skin.resources=ALL-UNNAMED',
            '--add-exports', 'javafx.controls/com.sun.javafx.scene.control.inputmap=ALL-UNNAMED',
            '--add-exports', 'javafx.graphics/com.sun.javafx.scene.traversal=ALL-UNNAMED',
            '--add-exports', 'javafx.graphics/com.sun.javafx.scene=ALL-UNNAMED',
            '--add-exports', 'javafx.graphics/com.sun.javafx.tk=ALL-UNNAMED',
            '--add-exports', 'javafx.graphics/com.sun.javafx.util=ALL-UNNAMED',
            '--add-opens', 'java.desktop/sun.swing=ALL-UNNAMED',
            '--add-opens', 'java.desktop/sun.awt.X11=ALL-UNNAMED'
        ]

    }
    sourceCompatibility = 11
    targetCompatibility = 11

    clean {
        delete += "dist-bin"
    }
}

subprojects {
    group 'biz.ganttproject'
    version = new Date().format("yy.MM.dd")
}


def addPublishing(project) {
    project.publishing {
        repositories {
            maven {
                name "ganttproject-maven-repository-internal"
                url "gcs://ganttproject-maven-repository/internal"
            }
        }
    }
}
//
//runtime {
//    distDir = rootProject.distBinDir
//    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
//    modules = ['java.base']
//}