#Copyright (c) 2019-2021 Huawei Device Co., Ltd.
#Licensed under the Apache License, Version 2.0 (the "License");
#you may not use this file except in compliance with the License.
#You may obtain a copy of the License at
#
#    http://www.apache.org/licenses/LICENSE-2.0
#
#Unless required by applicable law or agreed to in writing, software
#distributed under the License is distributed on an "AS IS" BASIS,
#WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
#See the License for the specific language governing permissions and
#limitations under the License.

if (defined(ohos_lite)) {
  config("cjson_config") {
    include_dirs = [ "." ]
    ldflags = [ "-lm" ]
    defines = [ "CJSON_NESTING_LIMIT=(128)" ]
  }
  cjson_sources = [
    "cJSON.c",
    "cJSON_Utils.c",
  ]

  if (defined(board_toolchain_type) && board_toolchain_type == "iccarm") {
    cflags = [
      "--diag_suppress",
      "Pe513",
    ]
    cflags_cc = cflags
  }
  static_library("cjson_static") {
    sources = cjson_sources
    public_configs = [ ":cjson_config" ]
  }

  shared_library("cjson_shared") {
    sources = cjson_sources
    public_configs = [ ":cjson_config" ]
  }
} else {
  import("//build/ohos.gni")
  config("cJSON_config") {
    include_dirs = [ "." ]
    defines = [ "CJSON_NESTING_LIMIT=(128)" ]
  }
  ohos_static_library("cjson_static") {
    sources = [ "cJSON.c" ]
    public_configs = [ ":cJSON_config" ]
    part_name = "cjson"
    subsystem_name = "thirdparty"
  }
  ohos_shared_library("cjson") {
    deps = [ ":cjson_static" ]
    public_configs = [ ":cJSON_config" ]
    part_name = "cjson"
    subsystem_name = "thirdparty"
    install_images = [
      "system",
      "updater",
    ]
  }
}