@echo off

set NGINX_DIR=D:\nginx-1.16.1\
set JAVA_DIR=D:\server\
set MAIN_CLASS=com.codejoys.monitor.App
set CP=%JAVA_DIR%config;%JAVA_DIR%lib\*;%JAVA_DIR%app\*


:INFO
  echo.
  echo --------------------- 前台进程 ---------------------
  tasklist|findstr /i "nginx.exe"
  if errorlevel 1 echo nginx未启动
  echo --------------------- 前台进程 ---------------------

  echo --------------------- 后台列表 ---------------------
  tasklist|findstr /i "javaw.exe"
  if errorlevel 1 echo java未启动
  echo --------------------- 后台进程 ---------------------

  echo.
  echo. 1. 启动服务器
  echo. 2. 关闭服务器
  echo. 3. 退出
  echo.
  echo 请输入功能序号：
  set /p id=
    if "%id%"=="1" goto START
    if "%id%"=="2" goto STOP
    if "%id%"=="3" exit
  pause

:START 
  if exist "%NGINX_DIR%nginx.exe" (
    cd /d %NGINX_DIR%
    start "" nginx.exe
    echo 启动前台成功
  ) else (
    echo "%NGINX_DIR%nginx.exe不存在"
  )

  cd /d %JAVA_DIR%
  start "" javaw -Xverify:none %JAVA_OPTS% -cp "%CP%" %MAIN_CLASS%
  echo 启动后台成功
  goto INFO

:STOP
  taskkill /F /IM nginx.exe > nul
  taskkill /F /IM javaw.exe > nul
  echo 已关闭所有nginx / java 进程
  goto INFO

goto :eof